Slipstream .NET 4.7 into Windows 10 x64 installation source, install.wim

CatOnRug solve, automate, speed up Slipstream .NET 4.7 into Windows 10 x64 installation source, install.wim
Use Windows ISO Downloader.exe to download Windows 10 image

I have this tested on Win10_1703_English_x64.iso
effccfda8a8dcf0b91bb3878702ae2d8
ce8005a659e8df7fe9b080352cb1c313c3e9adce

Download adksetup.exe and install "Deployment Tools".
Windows Assessment and Deployment Kit Wizard. Only Deployment Tools is gonna be installed

Download NDP47-KB3186497-x86-x64-AllOS-ENU.exe

Download windows10.0-kb4020102-x64_9d406340d67caa80a55bc056e50cf87a2e7647ce.msu



Optional step:
For zero touch install, I will save autounattend.xml

Download slipstream.cmd which contains:
@echo off
setlocal EnableDelayedExpansion

set path=%path%;%~dp0
rem this is tested on:
rem  iso: Win10_1703_English_x64.iso
rem  md5: effccfda8a8dcf0b91bb3878702ae2d8
rem sha1: ce8005a659e8df7fe9b080352cb1c313c3e9adce

rem "Deployment Tools" must be installed from ADK 10. download it here:
rem http://download.microsoft.com/download/3/8/B/38BBCA6A-ADC9-4245-BCD8-DAA136F63C8B/adk/adksetup.exe

rem I want to use latest DISM utility instead of the default
cd "C:\Program Files (x86)\Windows Kits\10\Assessment and Deployment Kit\Deployment Tools\amd64\DISM"
echo.

rem check if system is clear before doing anything
if exist "%temp%\mount" rd /Q /S "%temp%\mount"
if not !errorlevel!==0 break
if exist "%temp%\iso" rd /Q /S "%temp%\iso"
if not !errorlevel!==0 break

rem Create a temporary directory to extract iso content
if not exist "%temp%\iso" md "%temp%\iso"

rem Create a mounting directory
if not exist "%temp%\mount" md "%temp%\mount"

echo Extracting x64-Windows10.0-KB3186568-x64.cab to current directory..
7z e "%~dp0NDP47-KB3186497-x86-x64-AllOS-ENU.exe" -o"%~dp0" x64-Windows10.0-KB3186568-x64.cab -r -y > nul 2>&1
echo.

echo Extracting iso file..
7z x "%~dp0Win10_1703_English_x64.iso" -o"%temp%\iso" -y > nul 2>&1
echo.

echo Mounting install.wim
dism /mount-wim /wimfile:"%temp%\iso\sources\install.wim" /index:1 /mountdir:"%temp%\mount" > nul 2>&1
echo.

echo Integrating .NET 2.0, 3.0 and 3.5 into install.wim
dism /image:"%temp%\mount" /enable-feature /featurename:NetFx3 /all /limitaccess /source:"%temp%\iso\sources\sxs" > nul 2>&1
echo.

echo Integrating .NET 4.7 into install.wim
dism /image:"%temp%\mount" /add-package /packagepath:"%~dp0x64-Windows10.0-KB3186568-x64.cab" > nul 2>&1
echo.

echo Apply some updates..
dism /image:"%temp%\mount" /add-package /packagepath:"%~dp0windows10.0-kb4020102-x64_9d406340d67caa80a55bc056e50cf87a2e7647ce.msu" > nul 2>&1
echo.

echo Unmounting install.wim
dism /unmount-wim /mountdir:"%temp%\mount" /commit > nul 2>&1
echo.

echo Making max compression of install.wim
"C:\Program Files (x86)\Windows Kits\10\Assessment and Deployment Kit\Deployment Tools\amd64\DISM\dism.exe" /Export-Image /SourceImageFile:"%temp%\iso\sources\install.wim" /SourceIndex:1 /DestinationImageFile:"%temp%\install.wim" /Compress:max > nul 2>&1

rem replace install.wim with compressed
move /Y "%temp%\install.wim" "%temp%\iso\sources" > nul 2>&1
echo.

echo Enable zero touch installation
xcopy /Y "%~dp0autounattend.xml" "%temp%\iso" > nul 2>&1
echo.

echo Re-Creating iso file %~dp0win10x64dotnet47.iso
"C:\Program Files (x86)\Windows Kits\10\Assessment and Deployment Kit\Deployment Tools\amd64\Oscdimg\oscdimg.exe" -b"%temp%\iso\boot\etfsboot.com" -h -u2 -m -l"win10x64" "%temp%\iso" "%~dp0win10x64dotnet47.iso" > nul 2>&1
echo.

rem Clear mounting directory
if exist "%temp%\mount" rd /Q /S "%temp%\mount"

rem Clear ISO directory
if exist "%temp%\iso" rd /Q /S "%temp%\iso"

endlocal
pause
Right click on "slipstream.cmd" and select "Run As Administrator".

Wait 20 minutes or something.

Use file:
win10x64dotnet47.iso
Here is video how simple it is:

No comments:

Post a Comment