Deploy Flash Player 26.0.0.131 on Windows 7, offline installer

CatOnRug solve, automate, speed up Deploy Flash Player 26.0.0.131 on Windows 7, offline installer
This will:
  • deploy Adobe Flash Player Plugin for Firefox or other browsers
  • update Adobe Flash Player ActiveX plugin for Internet Explorer 11 on Windows 7
  • skip ActiveX plugin update on Windows 10 and 8.1 cause it happens via Windows Updates

command prompt window of adobe flash player deployment

To do it so download these files:
http://fpdownload.adobe.com/get/flashplayer/pdc/26.0.0.131/install_flash_player_ax.exe
3f9fd5b5e7c42372d62871a0426f3d3d
3ed58c152ab51e1509424b35df979bee5374b84e

http://fpdownload.adobe.com/get/flashplayer/pdc/26.0.0.131/install_flash_player.exe
95ae755513f87abc87f9c96a1e3ed4f1
c2b8c526448f24a74bcb2d1dffb69c271ac0dc2c

Here is installation scenario for Windows 7:
@echo off

rem set some variables
set sw=HKLM\SOFTWARE
set cv=Microsoft\Windows NT\CurrentVersion

rem latest version numbers
set FlashPlayerActiveX=26.0.0.131
set FlashPlayerPlugin=26.0.0.131

setlocal EnableDelayedExpansion

echo %date%
echo.

time /T
echo.

echo ============= BEFORE ==============
reg query %sw%\Macromedia\FlashPlayerActiveX > nul 2>&1
if !errorlevel!==0 (
echo FlashPlayerActiveX:
reg query %sw%\Macromedia\FlashPlayerActiveX /v Version | find "Version"
)

reg query %sw%\Macromedia\FlashPlayerPlugin > nul 2>&1
if !errorlevel!==0 (
echo FlashPlayerPlugin:
reg query %sw%\Macromedia\FlashPlayerPlugin /v Version | find "Version"
)

echo.

rem ActiveX version update happens via Windows Updates on Windows 8.1 or WIndows 10
reg query "%sw%\%cv%" /v ProductName | find "Windows 7" > nul 2>&1
if !errorlevel!==0 (


reg query %sw%\Macromedia\FlashPlayerActiveX > nul 2>&1
if !errorlevel!==0 reg query %sw%\Macromedia\FlashPlayerActiveX /v Version | find "%FlashPlayerActiveX%"
if not !errorlevel!==0 (

time /T
echo Installing Flash Player for Internet Explorer
start /wait "" "%~dp0install_flash_player_ax.exe" -install -au 2
echo !errorlevel!
echo.

time /T

) else echo FlashPlayerActiveX %FlashPlayerActiveX% version OK

) else echo Flash Player update on Windows 8.1/10 happens via Windows Updates
echo.

rem at first lets check if there is any Plugin is installed
reg query %sw%\Macromedia\FlashPlayerPlugin > nul 2>&1
rem if Plugin is installed lets compare version
if !errorlevel!==0 reg query %sw%\Macromedia\FlashPlayerPlugin /v Version | find "%FlashPlayerPlugin%" > nul 2>&1
rem if version no not match
if not !errorlevel!==0 (
time /T
echo Installing Flash Player for Firefox..
start /wait "" "%~dp0install_flash_player.exe" -install -au 2
echo !errorlevel!
echo.
time /T

) else echo FlashPlayerPlugin %FlashPlayerPlugin% already installed
echo.


echo ============= AFTER ===============
reg query %sw%\Macromedia\FlashPlayerActiveX > nul 2>&1
if !errorlevel!==0 (
echo FlashPlayerActiveX:
reg query %sw%\Macromedia\FlashPlayerActiveX /v Version | find "Version"
)

reg query %sw%\Macromedia\FlashPlayerPlugin > nul 2>&1
if !errorlevel!==0 (
echo FlashPlayerPlugin:
reg query %sw%\Macromedia\FlashPlayerPlugin /v Version | find "Version"
)
echo.

time /T
echo.

endlocal
pause

No comments:

Post a Comment